
(defun c:update_annotation_leader (/ oDoc blockRef blockName isDynamic lstBlockRefs ssAusw cnt propValue)
  (if (not vlax-get-acad-object) (vl-load-com))
  (setq oDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
  (if (and (setq blockRef (vl-catch-all-apply 'entsel (list "\r\nAnmerkungsobjekt wählen: ")))
	   (not (vl-catch-all-error-p blockRef))
	   (= (cdr (assoc 0 (entget (car blockRef)))) "INSERT")
	   (setq blockRef (vlax-ename->vla-object (car blockRef)))
	   (wcmatch (setq blockName (vla-get-effectivename blockRef)) "ACMAP_ANN_TEMPLATE*"))
    (progn
      (if (= (logand (getvar "UNDOCTL") 8) 8) (vla-EndUndoMark oDoc))
      (vla-StartUndoMark oDoc)
      
      (if (setq isDynamic (= (vla-get-IsDynamicBlock blockRef) :vlax-true))
	(progn
	  (setq lstBlockRefs '())
	  (repeat (setq cnt (sslength (setq ssAusw (ssget "X" (list (cons 0 "INSERT") (cons 410 "Model"))))))
	    (setq blockRef (vlax-ename->vla-object (ssname ssAusw (setq cnt (1- cnt)))))
	    (if (= (vla-get-effectivename blockRef) blockName)
	      (progn
		(setq lstBlockRefs (cons (cons blockRef
					       (mapcar '(lambda (x) (cons (strcase (vlax-get x 'PropertyName)) (vlax-get x 'Value)))
						       (vlax-safearray->list (vlax-variant-value (vla-GetDynamicBlockProperties blockRef)))
						       )) lstBlockRefs))
		(if (/= (vla-get-effectivename blockRef) (vla-get-name blockRef)) (vla-ResetBlock blockRef))
	      ); progn
	    ); if
	  ); repeat
	); progn
      ); if

      ;; Lisp-Variante nicht gefunden
      (vl-cmdf "_mapannrefresh" "_s")

      (foreach blockRef lstBlockRefs
	(mapcar '(lambda (x)
		   (if (setq propValue (assoc (strcase (vla-get-PropertyName x)) (cdr blockRef)))
		     (vla-put-value x (vlax-make-variant (cdr propValue) (vlax-variant-type (vla-get-value x))))
		   ); if
		 ); mapcar
		(vlax-invoke (car blockRef) 'GetDynamicBlockProperties))
      ); foreach

      (vla-EndUndoMark oDoc)
    ); progn
  ); if
  (princ)
); c:update_annotation_leader