(defun c:add_leader_to_block (/ oDoc blockRef posLeader minPoint maxPoint midPoint lstPoints posBlock oSpace oLeader)
  (if (not vlax-get-acad-object) (vl-load-com))
  (setq oDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
  (if (and (setq blockRef (vl-catch-all-apply 'entsel (list "\r\nBlock wählen: ")))
	   (not (vl-catch-all-error-p blockRef))
	   (= (cdr (assoc 0 (entget (car blockRef)))) "INSERT")
	   (setq blockRef (vlax-ename->vla-object (car blockRef)))
	   (setq posLeader (vl-catch-all-apply 'getpoint (list "\r\nPosition der Pfeilspitze wählen: ")))
	   (not (vl-catch-all-error-p posLeader))
	   (setq posLeader (reverse (cdr (reverse posLeader)))))
    (progn
      (if (= (logand (getvar "UNDOCTL") 8) 8) (vla-EndUndoMark oDoc))
      (vla-StartUndoMark oDoc)
      
      (vla-GetBoundingBox blockRef 'minPoint 'maxPoint)
      (setq minPoint (reverse (cdr (reverse (vlax-safearray->list minPoint))))
	    maxPoint (reverse (cdr (reverse (vlax-safearray->list maxPoint))))
	    midPoint (mapcar '* (mapcar '+ minPoint maxPoint) '(0.5 0.5))
	    lstPoints (list minPoint
			    (list (car midPoint) (cadr minPoint))
			    (list (car maxPoint) (cadr minPoint))
			    (list (car maxPoint) (cadr midPoint))
			    maxPoint
			    (list (car midPoint) (cadr maxPoint))
			    (list (car minPoint) (cadr maxPoint))
			    (list (car minPoint) (cadr midPoint)))
	    lstPoints (vl-sort lstPoints '(lambda (a b) (< (distance a posLeader) (distance b posLeader))))
	    posBlock (car lstPoints)
	    oSpace (if (or (= (getvar "TILEMODE") 1) (= (vla-get-MSpace oDoc) :vlax-true)) (vla-get-ModelSpace oDoc) (vla-get-PaperSpace oDoc))
	    oLeader (vl-catch-all-apply 'vla-AddLeader (list oSpace (vlax-make-variant (vlax-safearray-fill (vlax-make-safearray vlax-vbdouble (cons 0 5)) (list (car posLeader) (cadr posLeader) 0.0 (car posBlock) (cadr posBlock) 0.0))) blockRef acLineWithArrow)))

      (if (vl-catch-all-error-p oLeader) (princ (strcat "\r\nFehlgeschlagen: " (vl-catch-all-error-message oLeader))))
      (vla-EndUndoMark oDoc)
    ); progn
  ); if
  (princ)
); c:add_leader_to_block
